***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 21, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJA3411  D  G  S
Rg     G    1t    1
EVgs 3 2t  TABLE { V(S, 1t) }
+((0, 0)
+ (0.5 , 0.5  )
+ (1   , 1.1  )
+ (1.5 , 1.55 )
+ (1.75, 1.82 )
+ (2   , 2.00 )
+ (2.25, 2.17 )
+ (2.5 , 2.30 )
+ (2.75, 2.40 )
+ (3   , 2.50 )
+ (4.5 , 3.00 )
+ (10  , 4.50 )
+ (12  , 4.80 ))
EVgst   1    2t value = {8e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
M1      2    1    3    3    DMOS    L=1u   W=1u
.MODEL DMOS PMOS (
+  VTO = -0.92
+   KP = 13.8
+LEVEL =3)
Cgs    1t    3    4.719e-10
Rd      D    4    42.84e-3 tc=4.903e-3,-7.715e-6
Dds     4    3    DDS
.MODEL     DDS    D(IS=1.459E-13 N=1.085 RS=2.827e-1 eg=1.101 CJO=5.808e-11 M=2.724e-1 VJ=2.672e-1)
Dbody   D    3    DBODY
.MODEL   DBODY    D(IS=1.459E-13 N=1.085 RS=9.827e-2 eg=1.101 BV=22 IBV=250e-6 TBV1=3.472e-4 TT=25n)
Ra      4    2    18.33e-3
Rs      3    5    1e-4
Ls      5    S    0.001n
M2     1t    8    6    6   INTER
E2      8    6    4    1t   2
.MODEL   INTER    PMOS(VTO=0  KP=10   LEVEL=1)
Cgdmax  7    4    3.691e-10
Rcgd    7    4    10meg
Dgd     4    6    DGD
Rdgd    4    6    10meg
.MODEL     DGD    D(M=0.7123  CJO=3.082e-10   VJ=0.3476)
M3      7    9    1t    1t   INTER
E3      9    1t    4    1t   -2
.ENDS
*$
